在 Windows 11 (家用版) 上安裝啟用本機群組原則編輯器 (gpedit.msc)

發表於 分類於 文章字數： 316 所需閱讀時間 ≈ 1 分鐘

前言

我有需要在 Windows 11 家用版啟用 gpedit.msc，我決定製作一個啟用的批次檔(.bat)，並將幾個步驟與程序筆記下來。

安裝啟用 gpedit.msc

  1. 找一個純文字編輯器，可以使用 Windows 預設的「記事本」，我自己是使用 Notepad++(如下圖)。

  2. 把以下內容，貼進全新空白的檔案：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
@echo off
    
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"
    
pushd "%~dp0"

dir /b %SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientExtensions-Package~3*.mum >List.txt
dir /b %SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientTools-Package~3*.mum >>List.txt
    
for /f %%i in ('findstr /i . List.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"
pause

  1. 另存成一個批次檔(副檔名 .bat)，例如：gpeditmscEnabler。

  2. 執行 gpeditmscEnabler。

  3. 等候執行完成。

後記

  1. 執行這個批次檔之後，在同一個路徑底下，會生出一個 List.txt 的檔案，點開來其就是紀錄執行批次檔時，所安裝元件有哪幾支。

  2. gpedit.msc 是什麼的呢？這個部分，可參閱：群組原則 - 維基百科，自由的百科全書。